* Augmenting A Design;

/*
Sometimes it is desirable to augment a design in an optimal way.
Suppose it is expected that a linear model will suffice for the
experiment and so the design in design1 is run.
*/

data design1;
 input x1 x2;
cards;
-1 -1
 1 -1
-1  1
 0  0
 0  0
;
run;

/*
Later, the experimenters realized that a second-order design
would be more appropriate. They constructed a sensible list of
design points to include (based on a face-centered CCD).
*/

data candidate1;
 input x1 x2;
cards;
-1 -1
 1 -1
-1  1
 0  0
;
run;

data candidate2;
 input y1 y2;
cards;
 1  0
-1  0
 0  1
 0 -1
;
run;

/*
Then they evaluate the star points at a number of values, and find
the D-optimal augmentation at each.
*/

%macro augment_eg;
%do alpha=1 %to 4;

data candidate3;
 set candidate2;
 x1=&alpha*y1*.5;
 x2=&alpha*y2*.5;
 keep x1 x2;
run;

data candidates;
 set candidate1 candidate3;
run;

proc optex data=candidates;
 model x1|x2 x1*x1 x2*x2;
 generate n=15 augment=design1;
 examine design;
run;

%end;
quit;
%mend augment_eg;
%augment_eg;